View of /trunk/uia/vxa/configure.in

AC_INIT(zip/zipfile.c)
AC_CONFIG_AUX_DIR(vm/conf)

# First configure the vx32 VM.
AC_CONFIG_SUBDIRS(vm)

options=""
AC_SUBST(options)

# Check for required VX32 cross-compiler tools.
AC_DEFUN([ACX_VX32_TOOL],[
AC_CHECK_PROG([$1],[$2],[$2])dnl
if test -z "[$]$1"; then
	# Check for it in a standard "third-party install" location too.
	AC_CHECK_PROG([$1],[$2],[/opt/vx32/bin/$2],,
			[/opt/vx32/bin])
fi
if test -z "[$]$1"; then
	AC_MSG_ERROR(dnl
[You need to install GNU binutils and gcc-core
configured as a cross-compiler toolchain for '--target=vx32'.])
fi
])

AC_CHECK_PROG(PERL,perl,perl)
if test -z "$PERL"; then
	AC_MSG_ERROR([You need to install Perl.])
fi

ACX_VX32_TOOL(VX32_CC,vx32-gcc)dnl
ACX_VX32_TOOL(VX32_LD,vx32-ld)dnl
ACX_VX32_TOOL(VX32_AR,vx32-ar)dnl

AC_CHECK_TOOL(CC,gcc)
AC_CHECK_TOOL(LD,ld)
AC_CHECK_TOOL(AR,ar)

AC_SEARCH_LIBS(dlopen,dl,,
	AC_MSG_ERROR([Can't find dlopen - vxa requires shared libraries.]))

AC_PROG_INSTALL
AC_PROG_LN_S
AC_LIBTOOL_DLOPEN
AC_PROG_LIBTOOL

# Configuration options
AC_ARG_ENABLE(debug,
[  --enable-debug          internal debugging features and sanity checks],
[if test ["x${enableval}"] != xno; then
	DEFS="$DEFS -DDEBUG"
	options="debug $options"
fi])dnl


AC_OUTPUT(GNUmakefile)