View of /trunk/uia/vx32/configure.in

AC_INIT(vx/vx.h)
AC_CONFIG_AUX_DIR(conf)

# Generate a configuration header file.
AC_CONFIG_HEADERS([vx/config.h])
AH_TOP([
#ifndef CONFIG_H
#define CONFIG_H
])
AH_BOTTOM([
#endif // CONFIG_H
])

options=""
AC_SUBST(options)

# Determine the host architecture and OS combination,
# for selection system-specific directories and source files.
AC_CANONICAL_HOST
case $host in
	i*86-*-linux*)
		HOST_ARCH="x86/32"; HOST_OS="linux" ;;
	i*86-*-freebsd*)
		HOST_ARCH="x86/32"; HOST_OS="freebsd" ;;
	i*86-*-darwin*)
		HOST_ARCH="x86/32"; HOST_OS="macosx" ;;
	x86_64-*-linux*)
		HOST_ARCH="x86/64"; HOST_OS="linux" ;;
	*)
		AC_MSG_ERROR([Host $host not currently supported.])
		AC_MSG_WARN([No binary translator for $host:])
		AC_MSG_WARN([using slow instruction interpreter instead.])
		HOST_ARCH="interp" ;;
esac
AC_SUBST(HOST_ARCH)
AC_SUBST(HOST_OS)

# Check for required VX32 cross-compiler tools.
AC_DEFUN([ACX_VX32_TOOL],[
AC_CHECK_PROG([$1],[$2],[$2])dnl
if test -z "[$]$1"; then
	# Check for it in a standard "third-party install" location too.
	AC_CHECK_PROG([$1],[$2],[/opt/vx32/bin/$2],,
			[/opt/vx32/bin])
fi
if test -z "[$]$1"; then
	AC_MSG_ERROR(dnl
[You need to install GNU binutils and gcc-core
configured as a cross-compiler toolchain for '--target=vx32'.])
fi
])

AC_CHECK_PROG(PERL,perl,perl)
if test -z "$PERL"; then
	AC_MSG_ERROR([You must have Perl installed to compile the VM.])
fi

ACX_VX32_TOOL(VX32_CC,vx32-gcc)dnl
ACX_VX32_TOOL(VX32_LD,vx32-ld)dnl
ACX_VX32_TOOL(VX32_AR,vx32-ar)dnl

AC_CHECK_TOOL(CC,gcc)
AC_CHECK_TOOL(LD,ld)
AC_CHECK_TOOL(AR,ar)


# These are needed under linux to make off_t 64-bit.
AC_DEFINE(_LARGEFILE_SOURCE, 1, 
[This must be defined on some systems to enable large file support.])
AC_DEFINE(_FILE_OFFSET_BITS, 64,
[This must be set to 64 on some systems to enable large file support.])

# Check for presence of needed types.
AC_CHECK_TYPES([off_t, size_t, ssize_t])


AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_LIBTOOL
AC_CHECK_PROGS(LATEX,latex)
AC_CHECK_PROGS(DVIPS,dvips)
AC_CHECK_PROGS(PS2PDF,ps2pdf)

AC_C_BIGENDIAN

# Configuration options
AC_ARG_ENABLE(debug,
[  --enable-debug          internal debugging features and sanity checks],
[if test ["x${enableval}"] != xno; then
	DEFS="$DEFS -DDEBUG"
	options="debug $options"
fi])dnl


AC_OUTPUT(GNUmakefile)