View of /trunk/uia/uianet/configure.in

#                                               -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.
AC_INIT(uia, 0.01)
AC_PREREQ(2.59)
AC_CONFIG_SRCDIR([router/peerdb.C])
#AC_CONFIG_HEADER([config.h])
AC_CONFIG_AUX_DIR(misc)


# Top-level UIA object file directory
OBJDIR=`pwd`
AC_SUBST(OBJDIR)


# First configure YAM (Yet Another Mainloop),
# which can be distributed as an independent library
# but which we also distribute as a subtree of UIA.
# AC_CONFIG_SUBDIRS(yam)


# Determine the host OS for selection of system-specific sources.
AC_CANONICAL_HOST
case $host in 
	*linux*) 
		HOST_OS="linux" ;;
	*freebsd*) 
		HOST_OS="freebsd" ;;
	*apple*darwin*)
		HOST_OS="macos"
		QMAKE_FLAGS="-spec macx-g++" ;;
	*) 
		HOST_OS="unix" ;;
esac
AC_SUBST(HOST_OS)
AC_SUBST(QMAKE_FLAGS)


# Checks for programs.
AC_PROG_CXX
AC_PROG_CC
AC_PROG_CPP
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_LIBTOOL
dnl AC_PATH_PROGS(M4, gm4 gnum4 m4, '$(top_srcdir)/missing')
dnl AC_PATH_PROG(RPCGEN, rpcgen, '$(top_srcdir)/missing')

AC_CHECK_PROG(PERL,perl,perl)
if test -z "$PERL"; then
	AC_MSG_ERROR([You need Perl installed to compile UIA.])
fi

# Besides adding -I options to CPPFLAGS,
# also build a separate list of "bare" include dirs without -I prefixes,
# because that's what we need for Qt project files (ctl/uiactl.pro).
INCDIRS=""
AC_SUBST(INCDIRS)

# Similarly, build an absolute install pathname for Qt to use,
# because qmake uses different variable substitution operators...  (grrr)
PREFIX=$prefix
test "x$PREFIX" = xNONE && PREFIX=$ac_default_prefix
EXEC_PREFIX=$exec_prefix
test "x$EXEC_PREFIX" = xNONE && EXEC_PREFIX=$PREFIX
BINDIR=$bindir
test "x$BINDIR" = 'x${exec_prefix}/bin' && BINDIR=$EXEC_PREFIX/bin
AC_SUBST(BINDIR)

dnl UIA/YAM-specific tests
ACX_DEBUG
ACX_DMALLOC
ACX_PTHREADS
ACX_BOOST
ACX_BOOST_THREADS
ACX_BONJOUR
ACX_PYTHON
ACX_TWISTED
ACX_QT4
ACX_OPENSSL
ACX_YAM
ACX_LIBYAM

# Configure username account under which systemwide UIA daemons will run
AC_ARG_WITH(user,
	AC_HELP_STRING([--with-user=USER],
		[Run global UIA daemons as USER (default: uia)]), ,
	[with_user="uia"])
if test "$with_user" = "yes"; then
	AC_MSG_ERROR([You need to specify a username for --with-user.])
elif test "$with_user" = "no"; then
	with_user=""
fi
AC_SUBST(with_user)


# Form suitable defaults for etc, log, and run directories
# Using a --with option is really stupid and inappropriate,
# but autoconf's fascist non-changeable default for --localstatedir
# seems to be even worse.
AC_SUBST(with_confdir)
AC_ARG_WITH(confdir,
	AC_HELP_STRING([--with-confdir=DIR],
		[Place UIA config files in DIR/uia (default: /etc)]), ,
	[with_confdir="/etc"])
AC_SUBST(with_logdir)
AC_ARG_WITH(logdir,
	AC_HELP_STRING([--with-logdir=DIR],
		[Write UIA logs to DIR/uia (default: /var/log)]), ,
	[with_logdir="/var/log"])
AC_SUBST(with_rundir)
AC_ARG_WITH(rundir,
	AC_HELP_STRING([--with-rundir=DIR],
		[Store UIA run files in DIR/uia (default: /var/run)]), ,
	[with_rundir="/var/run"])

AC_SUBST(with_installconf)
AC_ARG_WITH(installconf,
	AC_HELP_STRING([--with-installconf=no],
                [Don't run uiaconfig as part of make install (default: run uiaconfig)]), ,
        [with_installconf="yes"])

AC_SUBST(with_installroot)
AC_ARG_WITH(installroot,
	AC_HELP_STRING([--with-installroot=DIR],
		[Use DIR as "/" for installation, useful for packaging (default: "")]), ,
	[with_installroot=""])

AC_SUBST(UIA_STATIC_QT)
AC_ARG_WITH(static-qt,
	AC_HELP_STRING([--with-static-qt=yes],
		[ (default: "no")]), 
        [UIA_STATIC_QT="UIA_STATIC_QT"],
	[UIA_STATIC_QT=""])

AC_DEFINE_UNQUOTED(UIA_CONFDIR, ["$with_confdir"], [description])

AC_OUTPUT([Makeconf])