View of /trunk/uia/netsteria/configure.in

#                                               -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.
AC_INIT(netsteria, 0.01)
AC_PREREQ(2.59)
AC_CONFIG_SRCDIR([lib/action.cc])
AC_CONFIG_AUX_DIR(misc)

AC_LANG([C++])

# Plain list of include directories without -I's, for qmake
INCS=""
AC_SUBST(INCS)

TOPSUBS=""
AC_SUBST(TOPSUBS)

# Check for required Qt 4 framework
AC_ARG_WITH(qt, AC_HELP_STRING([--with-qt=DIR],
		[Qt 4 toolkit location]))
if test -n "$with_qt"; then
	QMAKE="$with_qt/bin/qmake"
	if ! test -x $QMAKE; then
		AC_MSG_WARN([$QMAKE not found.])
		QMAKE=""
	fi
else
	AC_CHECK_PROGS(QMAKE,[qmake-qt4 qmake4 qmake])
fi
if test -n "$QMAKE"; then
	AC_MSG_CHECKING([Qt toolkit version])
	if test -n "$QMAKE" && ! ($QMAKE -v | grep -q "[Qt version 4[.][23456789]]"); then
		AC_MSG_RESULT([wrong version.])
		QMAKE=""
	else
		AC_MSG_RESULT([correct (version 4.2 or later).])
	fi
fi
if test -z "$QMAKE"; then
	AC_MSG_ERROR([Netsteria requires Qt toolkit version 4.2 or later.
		Please specify its location via '--with-qt=DIR',
		or see http://www.trolltech.com/ to obtain it.])
fi

# Check for OpenSSL crypto library
AC_ARG_WITH(qt, AC_HELP_STRING([--with-openssl=DIR],
		[OpenSSL install location]))
if test -n "$with_openssl"; then
	if test ! -f "$with_openssl/include/openssl/sha.h"; then
		AC_MSG_ERROR([Cannot find OpenSSL headers in '$with_openssl/include/openssl'])
	fi
	CXXFLAGS="$CXXFLAGS -I$with_openssl/include"
	INCS="$INCS $with_openssl/include"
	LIBS="$LIBS -L$with_openssl/lib"
fi
AC_CHECK_LIB(crypto,RAND_bytes,,
	[AC_MSG_ERROR([Netsteria requires OpenSSL version 0.9.8 or later.
		Please specify its location via '--with-openssl=DIR',
		or see http://www.openssl.org/ to obtain it.])])
AC_CHECK_DECL(NID_sha256,,
	[AC_MSG_ERROR([The installed version of OpenSSL appears to be too old;
		Netsteria requires OpenSSL version 0.9.8 or later.
		Please specify another location via '--with-openssl=DIR',
		or see http://www.openssl.org/ to obtain it.])],
	[#include "openssl/obj_mac.h"])


# Check for the Structured Session Transport library
AC_DEFUN([ACX_SST], [
AC_LANG_PUSH([C++])
# Check for SST source tree
AC_ARG_WITH(sst,
	AC_HELP_STRING([--with-sst=DIR],
		[SST library source tree location]))
if test -z "$with_sst" -a -f "sst/lib/host.h"; then
	# There's a copy of SST within the netsteria - use it.
	with_sst="$PWD/sst"
	TOPSUBS="$TOPSUBS sst"
fi
if test -n "$with_sst"; then
	# XX also allow referring to an SST install tree,
	# once SST actually becomes installable...
	if ! test -f $with_sst/lib/host.h; then
		AC_MSG_ERROR([SST library sources not found in '$with_sst'.])
	fi
	INCS="$INCS $with_sst/lib"
	LIBS="-L$with_sst -lsst $LIBS"
	CPPFLAGS="$CPPFLAGS -I$with_sst/lib"
	SST="$with_sst"
	AC_SUBST(SST)
else
	# If there's no --with-sst option and no embedded SST source tree,
	# then there'd better be an SST library already installed somewhere.
	# XXX does AC_CHECK_LIB support C++ namespaces?
	AC_CHECK_LIB(sst,SST::ba2bn,,
		[AC_MSG_ERROR([Netsteria requires the SST library.
			Please specify its location via '--with-sst=DIR'.])])
fi
AC_LANG_POP		dnl C++
])dnl ACX_BOOST

ACX_SST

AC_MSG_NOTICE([Configuration successful.])

AC_OUTPUT([top.pri])

# Run qmake at the very end, after generating top.pri,
# because top.pro depends on it.
$QMAKE || exit 1